How to calculate percentage in Excel

Definition

In this tutorial, you will lean a quick way to calculate percentages in Excel, find the basic percentage formula and a few more formulas for calculating percentage increase, percent of total and more.

Calculating percentage is useful in many areas of life, whether it is restaurant tipping, reseller commission, your income tax or interest rate. Say, you've been lucky enough to get a 25% off promotion code on a new plasma TV. Is this a good deal? And how much will you eventually have to pay?

In this tutorial, we are going to explore a few techniques that will help you efficiently calculate percent in Excel and learn the basic percentage formulas that will take the guesswork out of your calculations.

Percentage basics

The term "per cent" is derived from the Latin per centum, meaning "by the hundred". As you probably remember from high school math class, a percentage is a fraction of 100 that is calculated by dividing the numerator by the denominator and multiplying the result by 100.

The basic percentage formula is as follows:

(Part/Whole)*100 = Percentage

For example, if you had 20 apples and you gave 5 to your friends, how much did you give, percentage wise? By performing a simple calculation =5/20*100 you get the answer - 25%.

This is how you normally calculate percentages in school and everyday life. Computing percentage in Microsoft Excel is even easier since Excel performs some operations for you automatically, in the background.

Regrettably, there is no universal Excel formula for percentage that would cover all possible scenarios. If you ask someone "Which percent formula do I use to get the result I want?", most likely, you will get an answer like "Well, that depends on what exactly result you want to achieve."

So, let me show you a few simple formulas for calculating a percent in Excel such as a percentage increase formula, a formula to get percentages of a total and more.

Basic Excel percentage formula

The basic formula to calculate percentage in Excel is this:

Part/Total = Percentage

If you compare it to the basic math formula for percentage, you will notice that Excel's percentage formula lacks the *100 part. When calculating a percent in Excel, you do not have to multiply the resulting fraction by 100 since Excel does this automatically when the percentage format is applied to a cell.

And now, let's see how you can use the Excel percentage formula on real-life data. Suppose, you have the number of "Ordered items" in column B and "Delivered items" in column C. To find out the percentage of delivered products, perform the following steps:

• Enter the formula =C2/B2 in cell D2, and copy it down to as many rows as you need.
• Click the Percent Style button (Home tab > Number group) to display the resulting decimal fractions as percentages.

Remember to increase the number of decimal places if needed, as explained in Percentage tips.

• Done! : )

The same sequence of steps shall be performed when using any other percentage formula in Excel.

In the following example, column D displays a rounded percent of delivered items, without any decimal places showing.

Calculating percentage of total in Excel

In fact, the above example is a particular case of calculating percentages of a total. Now, let's investigate a few more examples that will help you make quick work of calculating a percent of a total in Excel on different data sets.

Example 1. The total is at the end of the table in a certain cell

A very common scenario is when you have a total in a single cell at the end of a table. In this case, the percentage formula will be similar to the one we've just discussed with the only difference that a cell reference in the denominator is absolute (with $).

For example, if you have some values in column B and their total in cell B10, you'd use the following formula to calculate percentages of the total: =B2/$B$10

You use a relative cell reference to cell B2 because you want it to get changed when you copy the formula to other cells of column B. But you enter $B$10 as an absolute cell reference because you want to leave the denominator fixed on B10 when auto-filling the formula down to row 9.

Tip. To make the denominator an absolute reference, either type the dollar sign ($) manually or click the cell reference in the formula bar and press F4.

The screenshot below demonstrates the results returned by the formula, the Percentages of Totalcolumn is formatted as percentage with 2 decimal places showing.

Example 2. Parts of the total are in multiple rows

In the above example, suppose you have several rows for the same product and you want to know what part of the total is made by all orders of that particular product.

In this case, you can use the SUMIF function to add up all numbers relating to a given product first, and then divide that number by the total, like this:

=SUMIF(range, criteria, sum_range) / total

Given that column A contains all product names, column B lists corresponding quantities, cell E1 is the name of the product you are interested in, and the total is in cell B10, your real-life formula may look similar to this:

=SUMIF(A2:A9 ,E1, B2:B9) / $B$10

Naturally, you can put the product name directly in the formula, like this:

=SUMIF(A2:A9, "cherries", B2:B9) / $B$10

If you want to find out what part of the total a few different products make, add up the results returned by several SUMIF functions, and then divide that number by the total. For example, the following formula calculates the percent of cherries and apples:

=(SUMIF(A2:A9, "cherries", B2:B9) + SUMIF(A2:A9, "apples", B2:B9)) / $B$10

For more information about the SUM function, please check out the following tutorials:

How to calculate percent change in Excel

Of all formulas for calculating percentage in Excel, a percent change formula is probably the one you would use most often.

Excel formula for percentage change (percentage increase / decrease)

To calculate percent change between values A and B, use the following formula:

(B - A) / A = Percent Change

When applying this formula to real data, it is important that you correctly determine which value is A and which is B. For example, yesterday you had 80 apples and how you have 100, meaning that now you have 20 apples more than before, which is 25% increase. If you had 100 apples and now you have 80, your number of apples has reduced by 20, which is 20% decrease.

Considering the above, our Excel formula for percentage change takes the following shape:

(New Value - Old Value) / Old Value = Percent Change

And now, let's see how you can use this percentage change formula (aka Excel percentage increase formula) in your spreadsheets.

Example 1. Calculating percent change between 2 columns

Suppose that you have the last month prices in column B and this month prices in column C. Then you can enter the following formula in cell D2 to calculate percentage change in your Excel sheet:

=(C2-B2)/B2

This percent change formula calculates the percentage increase / decrease in this month (column C) comparted to last month (column B).

After copying the formula to other rows, remember to click the Percent Style button on the ribbon to display decimals as percentages and you will get a result similar to what you see in the screenshot below. In this example, positive percentages that show percentage increase are formatted in usual black, while the negative percentages (percent decrease) are formatted in red by using the technique explained in this tip.

Example 2. Calculating percentage change between rows

In case you have one column of numbers, say column C that lists weekly or monthly sales, you can calculate percentage change using this formula:

=(C3-C2)/C2

Where C2 is the 1^st and C3 is the 2^nd cell with data.

Note. Please pay attention that you should skip the first row with data and put your Excel percentage formula into the 2^nd cell, which is D3 in this example.

After applying the percent format to the column with the percent change formula, you will get the following result:

If you want to calculate percentage change compared to a certain cell, then you need to fix the reference to that cell by using the absolute cell reference with the $ sign, e.g. $C$2.

For instance, here is the Excel percentage change formula that calculates the percent increase / decrease for each month compared to January (C2):

=(C3-$C$2)/$C$2

When you drag the formula down to copy it to other cells, the absolute reference ($C$2) will stay the same, while the relative reference (C3) will change to C4, C5 and so on.

Calculating amount and total by percentage

As you've just seen, calculating percentages in Excel is easy, and so is calculating amounts and totals if you know the percentage.

Example 1. Calculate amount by total and percentage

Suppose you are buying a new laptop for $950 and they charge 11% VAT on this purchase. The question is - how much do you have to pay on top of the net price? In other words, what is 11% of $950?

The following formula will help:

Total * Percentage = Amount

Assuming that the total value is in cell A2 and percent in B2, the above formula turns into a simple =A2*B2 and returns 104.50.

Remember, when you type a number followed by the percent sign (%) in Excel, the number is interpreted as a hundredth of its value. For example, 11% is actually stored as 0.11 and Excel uses this underlying value in all formulas and calculations.

In other words, the formula =A2*11% is equivalent to =A2*0.11. Naturally, you are free to use the decimal number corresponding to the percentage directly in a formula if this works better for your worksheets.

Example 2. Calculating total by amount and percentage

For example, you friend offered you his old computer for $400, which is 30% off the original price. You want to know what the original price was.

Since 30% is the discount, you deduct it from 100% first to know what percentage you actually have to pay (100% - 30% = 70%). Now you need the formula to calculate the original price, i.e. to find the number whose 70% equals 400.

The formula goes as follows:

Amount / Percentage = Total

Applied to real data, it may take any of the following shapes:

=A2/B2 or =A2/0.7 or =A2/70%

How to increase / decrease a number by percentage

The holiday season is upon us and this indicates a change in your usual weekly spendings. You may want to consider different options to find out your optimum weekly allowance.

To increase an amount by a percentage, use this formula:

= Amount * (1 + %)

For example, the formula =A1*(1+20%) increases the value in cell A1 by 20%.

To decrease an amount by a percentage:

= Amount * (1 - %)

For instance, the formula =A1*(1-20%) reduces the value in cell A1 by 20%.

In our example, if A2 is your current expenditures and B2 is the percentage you want to increase or reduce that amount by, here are the formulas you'd enter in cell C2:

Increase by percentage: =A2*(1+B2)

Reduce by percentage: =A2*(1-B2)

How to increase / reduce an entire column by a percentage

Suppose, you have a column of numbers that you want to increase or reduce by a certain percent, and you want to have the updated numbers in the same column rather than add a new column with the formula.

Here are 5 quick steps to handle this task:

1. Enter all the numbers you want to increase or decrease in some column, column B in this example.

2. In an empty cell, enter one of the below formulas:

Increase by percentage: =1+20%

Reduce by percentage: =1-20%

Naturally, you are free to replace 20% in the above formulas with the percentage you want.

3. Select the cell with the formula (C2 in our case) and copy it by pressing Ctrl + C.

4. Select the range of cells you want to change, right click the selection and then click Paste Special…

5. In the Paste Special dialog window, select Values under Paste, Multiply under Operation and click OK.

And here's the result - all the numbers in column B are increased by 20%:

In the same fashion, you can multiply or divide a column of numbers by a certain percentage. Simply enter the desired percentage in an empty cell and follow the steps above.